common-configs/zsh/customizations/zsh_tmux.zsh

export TMUX_CONF_DIR=${TMUX_CONF_DIR:-$__COMMON_CONFIGS/tmux}
export TMUX_STATUS_SCRIPT=${TMUX_STATUS_SCRIPT:-$TMUX_CONF_DIR/tmux.need-reboot.sh}

function tmux_running() {
  tmux -2 has-session -t "Nexus"
}

function tmux_init() {
  tmux -2 new-session -d -s "Nexus" 'LC_ALL=C.UTF-8 fortune | cowsay -f eyes -W "$COLUMNS"; exec "$SHELL" -i'
}

function tmux_start() {
  while ! tmux_running; do
    tmux_init
  done
}

function tmux_window() {
  tmux_start && tmux -2 new-window -t "Nexus" ${2:+-n} $2 'zsh -ic '${(qqqq)1}
}

function go_tmux() {
  if [[ "$TERM" == screen* ]] || [[ "$TERM" == tmux* ]]; then
    >&2 echo "You're already inside a tmux instance!"
    return 1
  fi
  echo "Starting tmux..."
  tmux_start || return
  if [[ $1 == "-x" ]]; then
    exec tmux -2 attach-session -t "Nexus" || return 1
  else
    tmux -2 attach-session -t "Nexus" || return 1
  fi
}

function auto_tmux ()
{
  if [[ -t 1 ]] && [[ -t 0 ]] && [[ -t 2 ]] && [[ "$TERM" != screen* ]] && [[ -z "$ALREADY_TRIED_STARTING_TMUX" ]]; then
    ALREADY_TRIED_STARTING_TMUX=true
    go_tmux -x
  fi
}