plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '1.3.21'
    id "ru.endlesscode.bukkitgradle" version "0.8.1"
    id 'com.google.protobuf' version '0.8.8'
}

group 'net.deliciousreya'
description 'A Minecraft plugin to allow players to create portals they can teleport between.'
version '0.1'

sourceCompatibility = 1.8

repositories {
    mavenCentral()
    maven {
        url 'https://papermc.io/repo/repository/maven-public/'
    }
}

configurations {
    shade
    compile.extendsFrom shade
}

dependencies {
    compileOnly bukkit()
    compileOnly group: 'com.destroystokyo.paper', name: 'paper-api', version: '1.16.3-R0.1-SNAPSHOT'
    shade "com.google.guava:guava:27.1-jre"
    shade "com.google.protobuf:protobuf-java:3.7.1"
    shade "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:3.0.0"
    }
    plugins {
        lite {
            artifact = "com.google.protobuf:protoc-gen-javalite:3.0.0"
        }
    }
}

bukkit {
    version = "1.16.3"

    // Attributes for plugin.yml
    meta {
        name = "PortalGenerator"
        description = "A Minecraft plugin to allow players to create portals they can teleport between."
        main = "net.deliciousreya.minecraftportal.MinecraftPortalPlugin"
        version = "0.1"
    }

    run {
        // Core type. It can be 'spigot' or 'paper'
        core = "paper"
        // Accept EULA
        eula = true
        // Set online-mode flag
        onlineMode = true
        // Debug mode (listen 5005 port, if you use running from IDEA this option will be ignored)
        debug = true
        // Set server encoding (flag -Dfile.encoding)
        encoding = "UTF-8"
        // JVM arguments
        javaArgs = "-Xmx1G"
        // Bukkit arguments
        bukkitArgs = ""
    }
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

jar {
    configurations.shade.each { dep ->
        from(project.zipTree(dep)) {
            exclude 'META-INF', 'META-INF/**'
        }
    }
}